Как разбить ячейки в Excel: «Текст по столбцам», «Мгновенное заполнение» и формулы

В этой статье Вы найдёте несколько способов, как разбить ячейки или целые столбцы в Excel 2010 и 2013. Приведённые примеры и скриншоты иллюстрируют работу с инструментами «Текст по столбцам» и «Мгновенное заполнение», кроме этого Вы увидите подборку формул для разделения имён, текстовых и числовых значений. Этот урок поможет Вам выбрать наилучший метод разбиения данных в Excel.

Говоря в общем, необходимость разбить ячейки в Excel может возникнуть в двух случаях: Во-первых, при импорте информации из какой-либо внешней базы данных или с веб-страницы. При таком импорте все записи копируются в один столбец, а нужно, чтобы они были помещены в разных столбцах. Во-вторых, при разбиении уже существующей таблицы, чтобы получить возможность качественнее настроить работу фильтра, сортировку или для более детального анализа.

Разбиваем ячейки в Excel при помощи инструмента «Текст по столбцам»

Инструмент «Текст по столбцам» действительно очень удобен, когда нужно разделить данные из одного столбца по нескольким в Excel 2013, 2010, 2007 или 2003.

«Текст по столбцам» позволяет разбивать значения ячеек, отделённые разделителями, или выделять данные фиксированной ширины (когда все значения содержат определённое количество символов). Давайте рассмотрим эти варианты подробнее:

Разбиваем текстовые данные с разделителями по столбцам в Excel

Предположим, есть список участников, приглашённых на конференцию или какое-то другое мероприятие. На рисунке ниже видно, что в столбце Participant (Участник) перечислены имена участников, государство и ожидаемая дата прибытия:

Разбиваем ячейки в Excel

Необходимо разбить этот текст на отдельные столбцы, чтобы таблица имела следующие данные (слева направо): First Name (Имя), Last Name (Фамилия), Country (Страна), Arrival Date (Ожидаемая дата прибытия) и Status (Статус).

  1. Если в таблице есть хотя бы один столбец справа от столбца, который необходимо разбить, тогда первым делом создайте новые пустые столбцы, в которые будут помещены полученные данные. Этот шаг необходим для того, чтобы результаты не были записаны поверх уже существующих данных.

    В нашем примере сразу после столбца Participant находится столбец Status, и мы собираемся добавить между ними новые столбцы Last Name, Country и Arrival Date.

    Если кто-то забыл, я напомню быстрый способ вставить сразу несколько столбцов на лист Excel. Для этого выберите столбец Status, кликнув по его заголовку, и, удерживая нажатой левую кнопку мыши, протащите указатель вправо, чтобы выделить нужное количество столбцов (сколько хотите вставить). Затем кликните правой кнопкой мыши по выделенной области и в контекстном меню выберите команду Insert (Вставить).

    Разбиваем ячейки в Excel

    Результат будет примерно таким, что Вы видите на рисунке ниже (новые столбцы вставлены слева от выделенных столбцов):

    Разбиваем ячейки в Excel

Примечание: Если у Вас нет столбцов, следующих непосредственно за тем, что Вы хотите разбить, то необходимость в этом шаге отпадает и его можно пропустить. Главное не упустите, что пустых столбцов должно быть не меньше, чем количество столбцов, на которое вы хотите разделить данные.

  1. Выделите столбец, который требуется разбить. Затем откройте вкладку Data (Данные) > Data Tools (Работа с данными) > Text to Columns (Текст по столбцам).

    Разбиваем ячейки в Excel

  2. Откроется диалоговое окно Convert Text to Columns wizard (Мастер распределения текста по столбцам). На первом шаге мастера Вы выбираете формат данных. Так как записи разделены пробелами и запятыми, мы выбираем формат Delimited (С разделителями). Вариант Fixed width (Фиксированной ширины) будет рассмотрен чуть позже. Если все готово, жмите Next (Далее), чтобы продолжить.

    Разбиваем ячейки в Excel

  3. На следующем шаге определяем разделители, которые содержатся в данных, и ограничитель строк.
    • Настраиваем разделители. Если данные разделены одним или несколькими разделителями, то нужно выбрать все подходящие варианты в разделе Delimiters (Символом-разделителем является) или ввести свой вариант разделителя в поле Other (Другой).

      В нашем примере мы выбираем Space (Пробел) и Comma (Запятая), а также ставим галочку напротив параметра Treat consecutive delimiters as one (Считать последовательные разделители одним). Этот параметр поможет избежать лишнего разбиения данных, например, когда между словами есть 2 или более последовательных пробела.

      Разбиваем ячейки в Excel

    • Настраиваем ограничитель строк. Этот параметр может понадобиться, если в столбце, который Вы разбиваете, содержатся какие-либо значения, заключённые в кавычки или в апострофы, и Вы хотите, чтобы такие участки текста не разбивались, а рассматривались как цельные значения. Например, если Вы выберите в качестве разделителя запятую, а в качестве ограничителя строк – кавычки ("), тогда любые слова, заключённые в кавычки (например, "California, USA"), будут помещены в одну ячейку. Если же в качестве ограничителя строк установить значение None (Нет), тогда слово "California" будет помещено в один столбец, а "USA" – в другой.

    В нижней части диалогового окна находится область Data preview (Образец разбора данных). Прежде чем нажать Next (Далее) будет разумным пролистать это поле и убедиться, что Excel правильно распределил все данные по столбцам.

  4. Осталось сделать всего две вещи – выбрать формат данных и указать, куда поместить разделённые ячейки.

    В разделе Column data format (Формат данных столбца) Вы можете выбрать формат данных отдельно для каждого столбца, в которые будут помещены разделённые данные. По умолчанию для всех столбцов задан формат General (Общий). Мы оставим его без изменений для первых трёх столбцов, а для четвёртого столбца установим формат Data (Дата), что логично, ведь в этот столбец попадут даты прибытия.

    Чтобы изменить формат данных для каждого конкретного столбца, выделите его, кликнув по нему в области Data preview (Образец разбора данных), а затем установите желаемый формат в разделе Column data format (Формат данных столбца).

    Разбиваем ячейки в Excel

    На этом же шаге мастера Вы можете выбрать, в какой столбец поместить разделённые данные. Для этого кликните по иконке выбора диапазона (в терминах Microsoft эта иконка называется Свернуть диалоговое окно) справа от поля Destination (Поместить в) и выберите крайний левый столбец из тех, в которые Вы хотите поместить разделённые данные. К сожалению, невозможно импортировать разделённые данные на другой лист или в другую рабочую книгу, попытка сделать это приведёт к сообщению об ошибке выбора конечной ссылки.

Совет: Если Вы не хотите импортировать какой-то столбец (столбцы), который показан в области Data preview (Образец разбора данных), то выделите его и выберите вариант Do not import column (Пропустить столбец) в разделе Column data format (Формат данных столбца).

  1. Нажмите Finish (Готово)!

    Разбиваем ячейки в Excel

Разбиваем текст фиксированной ширины по нескольким столбцам

Если данные состоят из текстовых или числовых значений с фиксированным количеством символов, Вы можете разбить их на несколько столбцов следующим способом.

К примеру, есть список товаров с ID и наименованием, причем идентификатор товара – это 9 символов, которые стоят перед наименованием этого товара:

Разбиваем ячейки в Excel

Вот что Вам нужно сделать, чтобы разбить такой столбец на два:

  1. Запустите инструмент Text to Columns (Текст по столбцам), как мы это делали в предыдущем примере. На первом шаге мастера выберите параметр Fixed width (Фиксированной ширины) и нажмите Next (Далее).

    Разбиваем ячейки в Excel

  2. В разделе Data preview (Образец разбора данных) настройте ширину столбцов. Как видно на рисунке ниже, край столбца символизирует вертикальная линия, и чтобы задать край следующего столбца, просто кликните в нужном месте. Двойной щелчок по вертикальной линии удалит край столбца, а если Вам нужно переместить границу столбца в другое место, просто перетащите вертикальную линию мышью. На самом деле, все эти инструкции подробно расписаны в верхней части диалогового окна :)

    Разбиваем ячейки в Excel

    Так как каждый ID товара содержит 9 символов, устанавливаем линию границы столбца на это значение, как показано на рисунке выше.

  3. На следующем шаге выберите формат данных и укажите ячейки, куда поместить результат, как это было сделано в предыдущем примере, а затем нажмите Finish (Готово).

Разбиваем объединённые ячейки в Excel

Если Вы объединили несколько ячеек на листе Excel и теперь хотите вновь разбить их по отдельным столбцам, откройте вкладку Home (Главная) и в группе команд Alignment (Выравнивание) нажмите маленькую чёрную стрелку рядом с кнопкой Merge & Center (Объединить и поместить в центре). Далее из выпадающего списка выберите Unmerge Cells (Отменить объединение ячеек).

Разбиваем ячейки в Excel

Таким образом объединение ячеек будет отменено, но удовольствие от результата будет испорчено тем, что все данные останутся в левом столбце. Думаю, Вы догадались, что нужно снова использовать функцию Text to Columns (Текст по столбцам), чтобы разбить данные из одного столбца на два или более столбцов.

Разделяем данные на несколько столбцов в Excel 2013 при помощи мгновенного заполнения

Если Вы уже обновились до Excel 2013, то можете воспользоваться преимуществами нового инструмента «Мгновенное заполнение» и заставить Excel автоматически заполнять (в нашем случае – разбивать) данные, при обнаружении определенной закономерности.

Если Вы ещё не знакомы с этой функцией, я попробую кратко объяснить её суть. Этот инструмент анализирует данные, которые Вы вводите на рабочий лист, и пытается выяснить, откуда они взялись и существует ли в них какая-либо закономерность. Как только «Мгновенное заполнение» распознает Ваши действия и вычислит закономерность, Excel предложит вариант, и последовательность записей в новом столбце появится буквально за мгновение.

Таким образом, при помощи этого инструмента Вы можете взять какую-то часть данных, находящихся в одном или нескольких столбцах, и ввести их в новый столбец. Думаю, Вы лучше поймёте о чём я говорю из следующего примера.

Первым делом, убедитесь, что инструмент «Мгновенное заполнение» включен. Вы найдёте этот параметр на вкладке File (Файл) > Options (Параметры) > Advanced (Дополнительно) > Automatically Flash Fill (Автоматически выполнять мгновенное заполнение).

Разбиваем ячейки в Excel

Теперь давайте посмотрим, как можно автоматически разбить данные по ячейкам. Итак, Вы включили инструмент «Мгновенное заполнение», и начинаете вводить с клавиатуры данные, которые нужно поместить в отдельные ячейки. По мере ввода Excel будет пытаться распознать шаблон в вводимых значениях, и как только он его распознает, данные автоматически будут вставлены в остальные ячейки. Чтобы понять, как это работает, посмотрите на рисунок ниже:

Разбиваем ячейки в Excel

Как видите, я ввёл только пару имён в столбец B, и «Мгновенное заполнение» автоматически заполнило остальные ячейки именами из столбца A. Если вы довольны результатом, просто нажмите Enter, и весь столбец будет заполнен именами. Очень умный инструмент, не правда ли?

Если «Мгновенное заполнение» включено, но не предлагает никаких вариантов, которые соответствуют определённому шаблону, Вы можете запустить этот инструмент вручную на вкладке Data (Данные) > Flash Fill (Мгновенное заполнение) или нажав сочетание клавиш Ctrl+E.

Разбиваем ячейки в Excel

Как в Excel разбивать ячейки при помощи формул

Существуют формулы, которые могут быть очень полезны, когда возникает необходимость разбить ячейки или столбцы с данными в Excel. На самом деле, следующих шести функций будет достаточно в большинстве случаев – LEFT (ЛЕВСИМВ), MID (ПСТР), RIGHT (ПРАВСИМВ), FIND (НАЙТИ), SEARCH (ПОИСК) и LEN (ДЛСТР). Далее в этом разделе я кратко объясню назначение каждой из этих функций и приведу примеры, которые Вы сможете использовать в своих книгах Excel.

Пример 1

Самая распространённая ситуация, когда могут понадобится эти формулы – это необходимость разделить имена из одного столбца по нескольким. На рисунке ниже показано, какого результата мы пытаемся достичь:

Разбиваем ячейки в Excel

Вы легко сможете разбить такие имена на два столбца при помощи следующих формул:

  • Извлекаем имя (столбец First name):

    =LEFT(A2,SEARCH(" ",A2,1)-1)
    =ЛЕВСИМВ(A2;ПОИСК(" ";A2;1)-1)

  • Извлекаем фамилию (столбец Last name):

    =RIGHT(A2,LEN(A2)-SEARCH(" ",A2,1))
    =ПРАВСИМВ(A2;ДЛСТР(A2)-ПОИСК(" ";A2;1))

Для тех, кому интересно, что означают эти формулы, я попробую объяснить более подробно.

SEARCH (ПОИСК) или FIND (НАЙТИ) – это абсолютно идентичные функции, которые выполняют поиск позиции определенной текстовой строки в заданной ячейке. Синтаксис формулы:

=SEARCH(find_text,within_text,[start_num])
=ПОИСК(искомый_текст;текст_для_поиска;[нач_позиция])

В качестве аргументов Вы должны указать: что нужно найти, где нужно искать, а также позицию символа, с которого следует начать поиск. В нашем примере SEARCH(" ",A2,1) или ПОИСК(" ";A2;1) говорит о том, что мы хотим найти символ пробела в ячейке A2 и начнём поиск с первого символа.

Замечание: Если поиск начинается с первого символа, Вы можете вообще пропустить аргумент start_num (нач_позиция) в формуле и упростить её до такого вида:

=LEFT(A2,SEARCH(" ",A2)-1)
=ЛЕВСИМВ(A2;ПОИСК(" ";A2)-1)

LEFT (ЛЕВСИМВ) и RIGHT (ПРАВСИМВ) – возвращает левую или правую часть текста из заданной ячейки соответственно. Синтаксис формулы:

=LEFT(text,[num_chars])
=ЛЕВСИМВ(текст;[количество_знаков])

В качестве аргументов указываем: какой текст взять и сколько символов извлечь. В следующем примере формула будет извлекать левую часть текста из ячейки A2 вплоть до позиции первого найденного пробела.

=LEFT(A2,SEARCH(" ",A2)-1)
=ЛЕВСИМВ(A2;ПОИСК(" ";A2)-1)

LEN (ДЛСТР) – считает длину строки, то есть количество символов в заданной ячейке. Синтаксис формулы:

=LEN(text)
=ДЛСТР(текст)

Следующая формула считает количество символов в ячейке A2:

=LEN(A2)
=ДЛСТР(A2)

Если имена в Вашей таблице содержат отчества или суффиксы, то потребуются немного более сложные формулы с использованием функции MID (ПСТР).

Пример 2

Вот такие формулы нужно использовать, когда имена, которые требуется разбить, содержат отчество или только один инициал отчества посередине.

A B C D
1 Полное имя Имя Отчество Фамилия
2 Sally K. Brooke Sally K. Brooke
  • Извлекаем имя:

    =LEFT(A2,FIND(" ",A2,1)-1)
    =ЛЕВСИМВ(A2;НАЙТИ(" ";A2;1)-1)

  • Извлекаем отчество:

    =MID(A2,FIND(" ",A2,1)+1,FIND(" ",A2,FIND(" ",A2,1)+1)-(FIND(" ",A2,1)+1))
    =ПСТР(A2;НАЙТИ(" ";A2;1)+1;НАЙТИ(" ";A2;НАЙТИ(" ";A2;1)+1)-(НАЙТИ(" ";A2;1)+1))

  • Извлекаем фамилию:

    =RIGHT(A2,LEN(A2)- FIND(" ",A2,FIND(" ",A2,1)+1))
    =ПРАВСИМВ(A2;ДЛСТР(A2)-НАЙТИ(" ";A2;НАЙТИ(" ";A2;1)+1))

Функция MID (ПСТР) – извлекает часть текстовой строки (то есть заданное количество символов). Синтаксис:

=MID(text,start_num,num_chars)
=ПСТР(текст;начальная_позиция;количество_знаков)

В качестве аргументов функции указываем: какой текст взять, позицию символа, с которого нужно начать, и сколько символов извлечь.

Пример 3

Вы можете использовать аналогичные формулы, чтобы разбить имена с суффиксами в конце:

A B C D
1 Полное имя Имя Фамилия Суффикс
2 Robert Furlan Jr. Robert Furlan Jr.
  • Извлекаем имя:

    =LEFT(A2,FIND(" ",A2,1)-1)
    =ЛЕВСИМВ(A2;НАЙТИ(" ";A2;1)-1)

  • Извлекаем фамилию:

    =MID(A2,FIND(" ",A2,1)+1,FIND(" ",A2,FIND(" ",A2,1)+1)-(FIND(" ",A2,1)+1))
    =ПСТР(A2;НАЙТИ(" ";A2;1)+1;НАЙТИ(" ";A2;НАЙТИ(" ";A2;1)+1)-(НАЙТИ(" ";A2;1)+1))

  • Извлекаем суффикс:

    =RIGHT(A2,LEN(A2)-FIND(" ",A2,FIND(" ",A2,1)+1))
    =ПРАВСИМВ(A2;ДЛСТР(A2)-НАЙТИ(" ";A2;НАЙТИ(" ";A2;1)+1))

Пример 4

А вот формулы, позволяющие разбить имена с фамилией, стоящей впереди и отделенной от имени запятой, и отчеством, находящимся в конце:

A B C D
1 Полное имя Имя Отчество Фамилия
2 White, David Mark David Mark White
  • Извлекаем имя:

    =MID(A2,SEARCH(" ",A2,1)+1,FIND(" ",A2,FIND(" ",A2,1)+1)-(FIND(" ",A2,1)+1))
    =ПСТР(A2;ПОИСК(" ";A2;1)+1;НАЙТИ(" ";A2;НАЙТИ(" ";A2;1)+1)-(НАЙТИ(" ";A2;1)+1))

  • Извлекаем отчество:

    =RIGHT(A2,LEN(A2)- FIND(" ",A2,FIND(" ",A2,1)+1))
    =ПРАВСИМВ(A2;ДЛСТР(A2)-НАЙТИ(" ";A2;НАЙТИ(" ";A2;1)+1))

  • Извлекаем фамилию:

    =LEFT(A2,FIND(" ",A2,1)-2)
    =ЛЕВСИМВ(A2;НАЙТИ(" ";A2;1)-2)

Пример 5

Как Вы понимаете, эти формулы работают не только для разделения имён в Excel. Вы можете использовать их для разбиения любых данных из одного столбца по нескольким. Например, следующие формулы Вы можете использовать, чтобы разбить текстовые данные, разделённые запятыми:

A B C D
1 Полное обозначение Штат Аббревиатура Столица
2 Alabama, AL, Montgomery Alabama AL Montgomery
  • Извлекаем название штата:

    =LEFT(A2,SEARCH(",",A2)-1)
    =ЛЕВСИМВ(A2;ПОИСК(",";A2)-1)

  • Извлекаем аббревиатуру штата:

    =MID(A2,SEARCH(",",A2)+2,SEARCH(",",A2,SEARCH(",",A2)+2)-SEARCH(",",A2)-2)
    =ПСТР(A2;ПОИСК(",";A2)+2;ПОИСК(",";A2;ПОИСК(",";A2)+2)-ПОИСК(",";A2)-2)

  • Извлекаем столицу штата:

    =RIGHT(A2,LEN(A2)-(SEARCH(",",A2,SEARCH(",",A2)+1)+1))
    =ПРАВСИМВ(A2;ДЛСТР(A2)-(ПОИСК(",";A2;ПОИСК(",";A2)+1)+1))

А вот пример реальных данных из Excel 2010. Данные из первого столбца разбиты на три отдельных столбца:

Разбиваем ячейки в Excel

04.08.2015 22:04
35777

Комментарии

Нет комментариев. Ваш будет первым!