30 функций Excel за 30 дней: ФИКСИРОВАННЫЙ (FIXED)

Вчера в ходе марафона 30 функций Excel за 30 дней мы извлекали элемент из списка при помощи функции CHOOSE (ВЫБОР) и выяснили, что для поиска гораздо удобнее использовать другие функции, например, VLOOKUP (ВПР) или MATCH (ПОИСКПОЗ).

Шестой день марафона мы проведём, изучая функцию FIXED (ФИКСИРОВАННЫЙ), которая форматирует число с дробной частью и разделителями и возвращает результат в текстовом формате. Полагаю, что это не должно сильно Вас удивить, поскольку функция FIXED (ФИКСИРОВАННЫЙ) принадлежит к категории текстовых. Заслуживает ли функция FIXED (ФИКСИРОВАННЫЙ) того, чтобы ей пользовались? Посмотрите примеры и решите сами.

Итак, давайте познакомимся с функцией FIXED (ФИКСИРОВАННЫЙ) поподробнее и рассмотрим несколько примеров работы с ней. Если у Вас есть чем дополнить описание или какие-то свои примеры, пожалуйста, делитесь ими в комментариях. Возможно, я пропустила какую-то удивительную возможность этой функции. Этот момент должен быть ЗАФИКСИРОВАН и исправлен!

Функция 06: FIXED (ФИКСИРОВАННЫЙ)

Функция FIXED (ФИКСИРОВАННЫЙ) округляет число до определённого количества десятичных знаков и возвращает результат в текстовом формате с разделителями разрядов или без.

Как можно использовать функцию FIXED (ФИКСИРОВАННЫЙ)?

Функция FIXED (ФИКСИРОВАННЫЙ) может преобразовывать числа в текстовый формат, округляя до указанного числа десятичных разрядов. Функция может быть полезной для узкого круга задач, таких как:

• Сравнение чисел, импортированных как текст из других приложений.
• Преобразование чисел в текстовую строку.

Синтаксис FIXED (ФИКСИРОВАННЫЙ)

Функция FIXED (ФИКСИРОВАННЫЙ) имеет вот такой синтаксис:

FIXED(number,decimals,no_commas)
ФИКСИРОВАННЫЙ(число;число_знаков;без_разделителей)

• number (число) — число, которое Вы желаете округлить и преобразовать в текст.
• decimals (число_знаков) — требуемое количество разрядов справа от десятичной точки. По умолчанию количество разрядов справа от десятичной точки равно 2. Если же указано отрицательное значение, то разряды округляются слева.
• Если аргумент no_commas (без_разделителей) равен FALSE (ЛОЖЬ) или не указан вовсе, то результат выводится с разделителями.
• Если аргумент no_commas (без_разделителей) равен TRUE (ИСТИНА), результат выводится без разделителей.

В ряде стран мира, в частности в Канаде, в качестве разделителя целой и дробной части используется точка, а для разделителей групп разрядов – запятая. Например: 32,187.57. В России же принято использовать запятую и пробел соответственно, т.е. 32 187,57. Прошу обратить на это внимание, поскольку статья является переводом канадского автора.

При желании Вы можете настроить разделители целой и дробной части, а также разделители групп разрядов. Сделать это можно в параметрах Microsoft Excel или в настройка региональных стандартов Вашей операционной системы.

Ловушки FIXED (ФИКСИРОВАННЫЙ)

Функция FIXED (ФИКСИРОВАННЫЙ) превращает число в текст, поэтому не используйте ее там, где необходимо числа оставить числами. Например, чтобы ограничить количество десятичных знаков в таблице данных графика, используйте форматирование чисел в ячейках или функцию ROUND (ОКРУГЛ).

Пример 1: Форматирование округлённого числа

Функция FIXED (ФИКСИРОВАННЫЙ) позволяет взять число, округлить его до определённого десятичного разряда, добавить разделители и вернуть результат в текстовом формате. Например, если в ячейку C2 ввести число 32187.5689231, то можно использовать функцию FIXED (ФИКСИРОВАННЫЙ), чтобы округлить его до двух знаков после десятичной точки и добавить разделители.

=FIXED(C2,2,FALSE)
=ФИКСИРОВАННЫЙ(C2;2;ЛОЖЬ)

Вместо использования функции FIXED (ФИКСИРОВАННЫЙ) вы можете просто применить к ячейке числовой формат с 2 десятичными знаками и разделителями. В таком случае содержимое ячейки не изменится, а изменится только форматирование.

Вы можете использовать функцию ROUND (ОКРУГЛ) в сочетании с форматированием ячейки, чтобы получить число с разделителями разрядов и округлённое до сотых долей.

=ROUND(C2,2)
=ОКРУГЛ(C2;2)

В конце концов, если Вам очень нужен результат в текстовом формате, используйте функцию TEXT (ТЕКСТ). Её возможности форматирования гораздо более гибкие, а если требуется округлить число, Вы можете использовать её в сочетании с функцией ROUND (ОКРУГЛ):

=TEXT(C2,"#,###.00?")
=ТЕКСТ(C2;"# ###,00?")

Пример 2: Округление разрядов слева от десятичной точки

С помощью функции FIXED (ФИКСИРОВАННЫЙ) можно округлять числа слева от десятичной точки, используя отрицательное число в качестве аргумента decimals (число_знаков). Чтобы убрать разделители, задайте значение аргумента no_commas (без_разделителей) равным TRUE (ИСТИНА). Как и прежде, мы получим результат в текстовом формате:

=FIXED(C2,-2,TRUE)
=ФИКСИРОВАННЫЙ(C2;-2;ИСТИНА)

Вы также можете использовать функцию ROUND (ОКРУГЛ), чтобы округлить число слева от десятичной точки.

=ROUND(C2,-2)
=ОКРУГЛ(C2;-2)

Пример 3: Отображение числа в тысячах долларов

Функция FIXED (ФИКСИРОВАННЫЙ) имеет ограниченные возможности форматирования и позволяет контролировать только количество знаков после десятичной точки и разделители разрядов. С помощью функции FIXED (ФИКСИРОВАННЫЙ) Вы можете округлить число до тысяч, но не сможете добавить знак доллара или спрятать нули.

=FIXED(C2,-3)
=ФИКСИРОВАННЫЙ(C2;-3)

Вместо использования функции FIXED (ФИКСИРОВАННЫЙ) Вы можете назначить пользовательский формат ячейке вида «$#,«. Он оставит без изменения содержимое ячейки, изменив только отображение.

Чтобы получить точно такой же результат в текстовом формате, используйте функцию TEXT (ТЕКСТ), которая позволит Вам задать формат числа в тысячах долларов.

=TEXT(C3,"$#,")
=ТЕКСТ(C3;"$# ")

Во втором выражении вместо запятой используется пробел. Применяйте такой формат, если у Вас в качестве разделителей разрядов используется пробел.