30 функций Excel за 30 дней: ПОВТОР (REPT)

Вчера в марафоне 30 функций Excel за 30 дней мы занимались простыми вещами с функцией T (Т). Она проверяет значение, чтобы узнать текстовое оно или нет, при этом существуют другие функции, которые могут выполнить ту же задачу.

15-й день марафона мы посвятим изучению функции REPT (ПОВТОР), которая повторяет текстовую строку заданное количество раз. Это ещё одна функция из категории текстовых, и она имеет несколько любопытных моментов.

Давайте внимательно посмотрим информацию и примеры по функции REPT (ПОВТОР). Если у Вас есть дополнительные сведения и примеры по этой функции, делитесь ими в комментариях.

Функция 15: REPT (ПОВТОР)

Функция REPT (ПОВТОР) повторяет текстовую строку заданное количество раз. Функция REPT (ПОВТОР) повторяет текстовую строку заданное количество раз. Функция REPT (ПОВТОР) повторяет текстовую строку заданное количество раз.

Создавать забавные эффекты, такие как в предыдущем абзаце, будет намного легче благодаря функции REPT (ПОВТОР). 🙂

Как можно использовать функцию REPT (ПОВТОР)?

Функция REPT (ПОВТОР) может быть использована, чтобы заполнить ячейку символом, а также в таких инновационных областях применения, как:

• Создание внутри ячейки индикатора процесса или точечной диаграммы.
• Ведение простого подсчёта.
• Поиск последнего текстового значения в столбце.

Синтаксис REPT (ПОВТОР)

Функция REPT (ПОВТОР) имеет следующий синтаксис:

REPT(text,number_times)
ПОВТОР(текст;число_повторений)

• text (текст) – текст, который надо повторить.
• number_times (число_повторений) – положительное число.

Ловушки REPT (ПОВТОР)

• Длина текстовой строки ограничена 32767 символами. Если будет больше, то формула сообщит об ошибке.
• Если number_times (число_повторений) будет дробным, оно будет отсечено до целого.
• Если number_times (число_повторений) будет равно 0, результатом окажется пустая строка.

Альтернативы REPT (ПОВТОР)

Если Вам нужно просто заполнить ячейку символом, достаточно использовать форматирование ячеек:

1. В ячейке введите символ(-ы), которым хотите её заполнить, например, дефис (-) или тильда (~).
2. Выделите эту ячейку и нажмите Ctrl+1, чтобы открыть окно Format Cells (Формат ячеек).
3. Зайдите на вкладку Alignment (Выравнивание) и в выпадающем списке Horizontal (По горизонтали) выберите Fill (С заполнением).
4. Нажмите ОК, чтобы закрыть диалоговое окно.

Символ заполнит ячейку. Если раздвинуть или сузить границы столбца, то заполнение ячейки будет следовать за изменением её размера.

Пример 1: Индикатор процесса внутри ячейки

Если у Вас установлена не одна из последних версий Excel со встроенными индикаторами процесса, Вы можете создать простой индикатор процесса внутри ячейки с помощью функции REPT (ПОВТОР). Например, чтобы создать индикатор процесса для целевого значения 100:

1. В ячейке B3 введите 100.
2. В ячейке C3 такую формулу:

   =REPT("n",B3/5)
=ПОВТОР("n";B3/5)

3. Для ячейки C3 задайте шрифт Wingdings (размер шрифта 9).
4. Установите подходящую ширину ячейки, чтобы индикатор мог поместиться полностью.
5. Теперь изменение числа в ячейке B3 будет изменять созданный нами индикатор.

В этом примере добавлено условное форматирование, чтобы выделить красным количество менее 60.

Пример 2: Точечная диаграмма внутри ячейки

Кроме индикаторов процесса, Вы можете создать простую точечную диаграмму внутри ячейки, используя функцию REPT (ПОВТОР). Например, чтобы создать точечную диаграмму для целевого значения 100:

1. В ячейке B3 введите 100.
2. В ячейке C3 следующую формулу:

   =REPT(" ",B3/5-1)&"o"
=ПОВТОР(" ";B3/5-1)&"o"

3. Установите подходящую ширину ячейки, чтобы индикатор мог поместиться полностью.
4. Теперь при изменении числа в ячейке B3 будет изменяться расположение символа «o«.

Пример 3: Ведение простого подсчёта

Если Вы потеряли свою доску для Криббеджа или занимаетесь подсчётом дней до следующего отпуска, можно использовать функцию REPT (ПОВТОР) для ведения подсчета заработанных очков или прошедших дней.

Чтобы сделать подсчёт при помощи функции REPT (ПОВТОР):

1. В ячейке B3 введите целевое значение, например, 25.
2. В ячейке C3 следующую формулу:

   =REPT("tttt ",INT(B3/5))&REPT("I",MOD(B3,5))
=ПОВТОР("tttt ";ЦЕЛОЕ(B3/5))&ПОВТОР("I";ОСТАТ(B3;5))

3. Задайте для ячейки шрифт Comic Sans или любой другой, в котором буква t прямая (в конце концов нашлось применение для Comic Sans!).
4. Установите подходящую ширину для столбца C. Если целевое число велико, можно увеличить высоту строки и включить перенос текста.
5. Измените число в ячейке C3, и подсчёт также изменится.

В результате эта формула покажет одну группу символов t для каждых 5 единиц счёта. А если есть остаток после деления количества на 5, этот остаток будет показан в конце строки в виде символов I – MOD(B3,5) или ОСТАТ(B3;5).

Пример 4: Поиск последнего текстового значения в списке

В сочетании с VLOOKUP (ВПР) Вы можете использовать функцию REPT (ПОВТОР), чтобы вернуть последнее текстовое значение в списке. Например, если в столбце D есть текстовые значения, используйте такую формулу для поиска последнего из них:

=VLOOKUP(REPT("z",255),D:D,1)
=ВПР(ПОВТОР("z";255);D:D;1)

Функция REPT (ПОВТОР) в этой формуле создаёт текстовую строку последней буквы алфавита (zzzz…), а VLOOKUP (ВПР) не сможет найти такую строку. В итоге, в режиме поиска приблизительного соответствия, будет выбрано последнее текстовое значение в списке.