30 функций Excel за 30 дней: СОВПАД (EXACT)

Добро пожаловать на подборку занятий 30 функций Excel за 30 дней (30XL30D). Спасибо, что приняли участие в опросе на тему самых интересных функций. В данной подборке мы сделаем обзор 30 лидирующих функций Excel (по результатам проведённого опроса), из следующих категорий:

• Текст
• Информация
• Поиск и ссылки

В конце этого 30-дневного марафона, будет опубликован список всех упомянутых функций в порядке, соответствующем количеству набранных в опросе голосов. Тем не менее, 30 самых популярных функций будут рассмотрены в случайном порядке, так что заходите сюда каждый день, чтобы ничего не пропустить.

Дадим старт нашему марафону и в качестве первой функцию возьмём EXACT (СОВПАД). Вы увидите 7 примеров использования этой функции, так что приготовьтесь удивляться её возможностям. Если у Вас есть свои приёмы или примеры использования этой функции, пожалуйста, поделитесь ими в комментариях.

Функция 01: EXACT (СОВПАД)

Функция EXACT (СОВПАД) может проверить две текстовые строки на предмет точного совпадения, причем, с учётом регистра. Форматирование на результат не влияет. Если совпадение строк точное, то функция возвращает значение TRUE (ИСТИНА), если же точного совпадения нет, то FALSE (ЛОЖЬ).

Как можно использовать функцию EXACT (СОВПАД)?

Кроме проверки двух ячеек на предмет точного совпадения, Вы можете выполнять при помощи функции EXACT (СОВПАД) следующие действия:

• Использовать для проверки данных, чтобы блокировать изменения в ячейке.
• Задавать условие на ввод только символов в верхнем регистре.
• Проверять точное совпадение в списке значений.
• Находить точное совпадение при поиске в таблице.
• Подсчитывать количество точных совпадений в списке.
• Выявлять различия между двумя ячейками.

Синтаксис EXACT (СОВПАД)

Функция EXACT (СОВПАД) имеет следующий синтаксис:

EXACT(text1,text2)
СОВПАД(текст1;текст2)

• text1 (текст1) – это первая текстовая строка.
• text2 (текст2) – это вторая текстовая строка.

Аргументы text1 и text2 можно ввести как текстовые строки или как ссылки на другие ячейки. В Excel максимальная длина строки для EXACT (СОВПАД) составляет 32767 символов.

Ловушки EXACT (СОВПАД)

В справке Excel 2007 в разделе Примечания для функции EXACT (СОВПАД) существует такая строка:

Возможно также использовать двойной знак равно (==) вместо функции EXACT (СОВПАД), чтобы произвести точное сравнение. Например, =A1==B1 возвратит такой же результат, как =СОВПАД(A1;B1).

Это не верно. В Excel нет оператора — двойной знак равно (==), и уже в справке к Microsoft Excel 2010 это примечание было убрано.

Пример 1: Проверка пароля

Представьте, что Вы ввели секретный пароль в одну из ячеек своей книги Excel и назвали эту ячейку pwd.

• На рисунке ниже секретный пароль находится в ячейке C2 с именем pwd. Она располагается на листе AdminData, который может быть скрыт от пользователей.

На другом листе пользователи будут вводить пароль, а Вы проверять его, используя функцию EXACT (СОВПАД).

• На листе Ex01 пользователь будет вводить пароль в ячейку C3.
• В ячейке C5 с помощью оператора равенства (=) сравниваем значения в ячейках C3 и pwd:

  =C3=pwd

• В ячейке C6 функция EXACT (СОВПАД) сравнивает ячейки C3 и pwd с учётом регистра:

  =EXACT(C3,pwd)
=СОВПАД(C3;pwd)

Если содержимое двух ячеек совпадает, включая регистр, то результатом в обоих случаях будет TRUE (ИСТИНА). Какие-либо различия в форматировании (например, жирный шрифт) будут проигнорированы.

Если хотя бы одна буква введена в другом регистре, то результатом в ячейке C6 будет FALSE (ЛОЖЬ).

Пример 2: Разрешение на изменение ячейки

После того, как пользователь ввел правильный пароль, Вы можете открыть доступ к изменению некоторых ячеек таблицы. Например, создав формулу для проверки данных в ячейке C5, можно контролировать в ней изменения значений.

Используя такую формулу в диалоговом окне Data Validation (Проверка данных), пользователи могут ввести значение в ячейку C5 только в том случае, если пароль, введённый в ячейку C3, полностью соответствует секретному паролю, сохранённому в ячейке pwd. Кроме того, значение в ячейке C5 должно быть больше 0 и меньше 0,1.

=AND(EXACT(C3,pwd),C5>0,C5<0.1)
=И(СОВПАД(C3;pwd);C5>0;C5<0,1)

Пример 3: Условие на ввод только символов в верхнем регистре

Вы можете использовать функцию EXACT (СОВПАД) для проверки, что в ячейку введены только буквы верхнего регистра. Например, канадский почтовый индекс имеет установленный формат с чередующимися цифрами и буквами верхнего регистра, например, L9L 9L9.

В ячейке C2 проверка данных была установлена с применением формулы:

=EXACT(C2,upper(C2))
=СОВПАД(C2;ПРОПИСН(C2))

Если в ячейку введены буквы нижнего регистра, появится предупреждение об ошибке. Конечно же, это не спасёт от всех возможных ошибок при записи почтового индекса, но будьте уверены – все буквы будут в верхнем регистре.

Пример 4: Найти точное совпадение в списке

Вместо простого сравнения ячеек, иногда требуется найти точное совпадение в списке значений. Например, если кто-то напишет код товара в ячейке, как проверить соответствует ли этот код какому-то товару из Вашего списка?

В следующем примере коды товаров записаны в ячейках B2:B5. Клиент может заказать товар, введя его код в ячейке E2.

Формула в ячейке F2 использует функцию EXACT (СОВПАД), чтобы проверить код, введённый в ячейку E2 на точное совпадение с нашим списком.

Формула введена, как формула массива, нажатием Ctrl+Shift+Enter.

{=OR(EXACT($B$2:$B$5,E2))}
{=ИЛИ(СОВПАД($B$2:$B$5;E2))}

Пример 5: Вернуть название по точному совпадению в списке

При поиске в таблице функция EXACT (СОВПАД) может отличить AA1 от Aa1, что позволяет найти правильное название продукта отдельно по каждому коду. Другие функции поиска, такие как VLOOKUP (ВПР), будут рассматривать такие коды как идентичные, и вернут результат, который первым попадётся в списке с таким кодом.

В следующем примере коды продуктов находятся в диапазоне B2:B5, покупатель может заказать продукт, введя его код в ячейку D2.

Формула в ячейке E2 использует 3 функции – INDEX (ИНДЕКС), MATCH (ПОИСКПОЗ) и EXACT (СОВПАД)

• Функция EXACT (СОВПАД) проверяет код, введённый в ячейке D2, и ищет точное совпадение в списке товаров.
• Функция MATCH (ПОИСКПОЗ) возвращает номер строки таблицы, в которой предыдущая функция нашла совпадение. В нашем случае код bG8943TO найден во второй строке диапазона.
• Функция INDEX (ИНДЕКС) возвращает значение из второй строки диапазона A2:A5, т.е. Sam.

Формула введена, как формула массива, нажатием Ctrl+Shift+Enter.

{= INDEX($A$2:$A$5,MATCH(TRUE,EXACT($B$2:$B$5,D2),0))}
{=ИНДЕКС($A$2:$A$5;ПОИСКПОЗ(ИСТИНА;СОВПАД($B$2:$B$5;D2);0))}

Пример 6: Подсчитать точные совпадения в списке

При поиске в таблице функция EXACT (СОВПАД) может отличить Aa1 от AA1, что позволяет подсчитать правильное количество отдельно по каждому коду. Другие функции, такие как COUNTIF (СЧЁТЕСЛИ), будут рассматривать такие коды как идентичные и посчитают их общее количество.

В следующем примере список повторяющихся значений находится в диапазоне A2:A11, а список уникальных значений в столбце C.

Формула в столбце D использует две функции – SUMPRODUCT (СУММПРОИЗВ) и EXACT (СОВПАД)

• Функция EXACT (СОВПАД) смотрит, что введено в столбец C, и проверяет, есть ли точное совпадение в списке элементов A2:A11.
• Функция SUMPRODUCT (СУММПРОИЗВ) возвращает общее количество, которое складывается из результатов TRUE (ИСТИНА)

=SUMPRODUCT(--EXACT($A$2:$A$11,C2))
=СУММПРОИЗВ(--СОВПАД($A$2:$A$11;C2))

Два знака минус (двойное отрицание) перед функцией EXACT (СОВПАД) превращают значения TRUE (ИСТИНА) и FALSE (ЛОЖЬ) соответственно в 1 и 0.

Пример 7: Проверить каждый символ в ячейке

Самое простое, что может сделать для Вас функция EXACT (СОВПАД) – подсказать есть ли точное совпадение между двумя текстовыми строками. Но иногда при несоответствии строк требуется определить, какие именно символы не совпадают. В следующем примере в каждой текстовой строке содержится по 6 символов. Также есть 6 столбцов, заголовки которых пронумерованы от 1 до 6.

Формула в ячейке C2 составлена из трёх функций, среди которых MID (ПСТР) и EXACT (СОВПАД).

• Функция MID (ПСТР) возвращает определённый символ из ячеек A2 и B2. Выбор позиции символа в тексте происходит по номеру столбца, содержащего формулу. Например, формула в ячейке C2, проверяет первые символы каждой текстовой строки, поскольку этот столбец имеет номер 1.
• Функция EXACT (СОВПАД) сравнивает два символа, извлечённых из текста при помощи двух функций MID (ПСТР).

=EXACT(MID($A2,C$1,1),MID($B2,C$1,1))
=СОВПАД(ПСТР($A2;C$1;1);ПСТР($B2;C$1;1))