Как посчитать процент в Excel?

В этом уроке Вы увидите, как при помощи Excel быстро вычислить проценты, познакомитесь с основной формулой расчёта процентов и узнаете несколько хитростей, которые облегчат Вашу работу с процентами. Например, формула расчёта процентного прироста, вычисление процента от общей суммы и кое-что ещё.

Умение работать с процентами может оказаться полезным в самых разных сферах жизни. Это поможет Вам, прикинуть сумму чаевых в ресторане, рассчитать комиссионные, вычислить доходность какого-либо предприятия и степень лично Вашего интереса в этом предприятии. Скажите честно, Вы обрадуетесь, если Вам дадут промокод на скидку 25% для покупки новой плазмы? Звучит заманчиво, правда?! А сколько на самом деле Вам придётся заплатить, посчитать сможете?

В этом руководстве мы покажем несколько техник, которые помогут Вам легко считать проценты с помощью Excel, а также познакомим Вас с базовыми формулами, которые используются для работы с процентами. Вы освоите некоторые хитрости и сможете отточить Ваши навыки, разбирая решения практических задач по процентам.

Базовые знания о процентах

Термин Процент (per cent) пришёл из Латыни (per centum) и переводился изначально как ИЗ СОТНИ. В школе Вы изучали, что процент – это какая-то часть из 100 долей целого. Процент рассчитывается путём деления, где в числителе дроби находится искомая часть, а в знаменателе – целое, и далее результат умножается на 100.

Основная формула для расчёта процентов выглядит так:

(Часть/Целое)*100=Проценты

Пример: У Вас было 20 яблок, из них 5 Вы раздали своим друзьям. Какую часть своих яблок в процентах Вы отдали? Совершив несложные вычисления, получим ответ:

(5/20)*100 = 25%

Именно так Вас научили считать проценты в школе, и Вы пользуетесь этой формулой в повседневной жизни. Вычисление процентов в Microsoft Excel – задача ещё более простая, так как многие математические операции производятся автоматически.

К сожалению, нет универсальной формулы для расчёта процентов на все случаи жизни. Если задать вопрос: какую формулу для расчёта процентов использовать, чтобы получить желаемый результат, то самым правильным ответом будет: всё зависит от того, какой результат Вы хотите получить.

Я хочу показать Вам некоторые интересные формулы для работы с данными, представленными в виде процентов. Это, например, формула вычисления процентного прироста, формула для вычисления процента от общей суммы и ещё некоторые формулы, на которые стоит обратить внимание.

Основная формула расчёта процента в Excel

Основная формула расчёта процента в Excel выглядит так:

Часть/Целое = Процент

Если сравнить эту формулу из Excel с привычной формулой для процентов из курса математики, Вы заметите, что в ней отсутствует умножение на 100. Рассчитывая процент в Excel, Вам не нужно умножать результат деления на 100, так как Excel сделает это автоматически, если для ячейки задан Процентный формат.

А теперь посмотрим, как расчёт процентов в Excel может помочь в реальной работе с данными. Допустим, в столбец В у Вас записано некоторое количество заказанных изделий (Ordered), а в столбец С внесены данные о количестве доставленных изделий (Delivered). Чтобы вычислить, какая доля заказов уже доставлена, проделаем следующие действия:

  • Запишите формулу =C2/B2 в ячейке D2 и скопируйте её вниз на столько строк, сколько это необходимо, воспользовавшись маркером автозаполнения.
  • Нажмите команду Percent Style (Процентный формат), чтобы отображать результаты деления в формате процентов. Она находится на вкладке Home (Главная) в группе команд Number (Число).
  • При необходимости настройте количество отображаемых знаков справа от запятой.
  • Готово!

Если для вычисления процентов в Excel Вы будете использовать какую-либо другую формулу, общая последовательность шагов останется та же.

В нашем примере столбец D содержит значения, которые показывают в процентах, какую долю от общего числа заказов составляют уже доставленные заказы. Все значения округлены до целых чисел.

Считаем проценты в Excel

Расчёт процента от общей суммы в Excel

На самом деле, пример, приведённый выше, есть частный случай расчёта процента от общей суммы. Чтобы лучше понять эту тему, давайте рассмотрим ещё несколько задач. Вы увидите, как можно быстро произвести вычисление процента от общей суммы в Excel на примере разных наборов данных.

Пример 1. Общая сумма посчитана внизу таблицы в конкретной ячейке

Очень часто в конце большой таблицы с данными есть ячейка с подписью Итог, в которой вычисляется общая сумма. При этом перед нами стоит задача посчитать долю каждой части относительно общей суммы. В таком случае формула расчёта процента будет выглядеть так же, как и в предыдущем примере, с одним отличием – ссылка на ячейку в знаменателе дроби будет абсолютной (со знаками $ перед именем строки и именем столбца).

Например, если у Вас записаны какие-то значения в столбце B, а их итог в ячейке B10, то формула вычисления процентов будет следующая:

=B2/$B$10

Для ячейки B2 используем относительную ссылку, чтобы она изменялась, когда мы скопируем формулу в другие ячейки столбца B. Ссылка на ячейку в знаменателе должна оставаться неизменной при копировании формулы, поэтому мы записали её как $B$10.

Подсказка: Есть два способа сделать ссылку на ячейку в знаменателе абсолютной: либо ввести знак $ вручную, либо выделить в строке формул нужную ссылку на ячейку и нажать клавишу F4.

На рисунке ниже показан результат вычисления процента от общей суммы. Для отображения данных выбран Процентный формат с двумя знаками после запятой.

Считаем проценты в Excel

Пример 2. Части общей суммы находятся в нескольких строках

Представьте себе таблицу с данными, как в предыдущем примере, но здесь данные о продуктах разбросаны по нескольким строкам таблицы. Требуется посчитать, какую часть от общей суммы составляют заказы какого-то конкретного продукта.

В этом случае используем функцию SUMIF (СУММЕСЛИ). Эта функция позволяет суммировать только те значения, которые отвечают какому-то определенному критерию, в нашем случае — это заданный продукт. Полученный результат используем для вычисления процента от общей суммы.

=SUMIF(range,criteria,sum_range)/total
=СУММЕСЛИ(диапазон;критерий;диапазон_суммирования)/общая сумма

В нашем примере столбец A содержит названия продуктов (Product) – это диапазон. Столбец B содержит данные о количестве (Ordered) – это диапазон_суммирования. В ячейку E1 вводим наш критерий — название продукта, по которому необходимо рассчитать процент. Общая сумма по всем продуктам посчитана в ячейке B10. Рабочая формула будет выглядеть так:

=SUMIF(A2:A9,E1,B2:B9)/$B$10
=СУММЕСЛИ(A2:A9;E1;B2:B9)/$B$10

Считаем проценты в Excel

Кстати, название продукта можно вписать прямо в формулу:

=SUMIF(A2:A9,"cherries",B2:B9)/$B$10
=СУММЕСЛИ(A2:A9;"cherries";B2:B9)/$B$10

Если необходимо вычислить, какую часть от общей суммы составляют несколько разных продуктов, то можно просуммировать результаты по каждому из них, а затем разделить на общую сумму. Например, так будет выглядеть формула, если мы хотим вычислить результат для cherries и apples:

=(SUMIF(A2:A9,"cherries",B2:B9)+SUMIF(A2:A9,"apples",B2:B9))/$B$10
=(СУММЕСЛИ(A2:A9;"cherries";B2:B9)+СУММЕСЛИ(A2:A9;"apples";B2:B9))/$B$10

Как рассчитать изменение в процентах в Excel

Одна из самых популярных задач, которую можно выполнить с помощью Excel, это расчёт изменения данных в процентах.

Формула Excel, вычисляющая изменение в процентах (прирост/уменьшение)

Чтобы рассчитать процентное изменение между значениями A и B, используйте следующую формулу:

(B-A)/A = Изменение в процентах

Используя эту формулу в работе с реальными данными, очень важно правильно определить, какое значение поставить на место A, а какое – на место B.

Пример: Вчера у Вас было 80 яблок, а сегодня у Вас есть 100 яблок. Это значит, что сегодня у Вас на 20 яблок больше, чем было вчера, то есть Ваш результат – прирост на 25%. Если же вчера яблок было 100, а сегодня 80 – то это уменьшение на 20%.

Итак, наша формула в Excel будет работать по следующей схеме:

(Новое значение – Старое значение) / Старое значение = Изменение в процентах

А теперь давайте посмотрим, как эта формула работает в Excel на практике.

Пример 1. Расчёт изменения в процентах между двумя столбцами

Предположим, что в столбце B записаны цены прошлого месяца (Last month), а в столбце C — цены актуальные в этом месяце (This month). В столбец D внесём следующую формулу, чтобы вычислить изменение цены от прошлого месяца к текущему в процентах.

=(C2-B2)/B2

Эта формула вычисляет процентное изменение (прирост или уменьшение) цены в этом месяце (столбец C) по сравнению с предыдущим (столбец B).

После того, как Вы запишите формулу в первую ячейку и скопируете её во все необходимые строки, потянув за маркер автозаполнения, не забудьте установить Процентный формат для ячеек с формулой. В результате у Вас должна получиться таблица, подобная изображённой на рисунке ниже. В нашем примере положительные данные, которые показывают прирост, отображаются стандартным чёрным цветом, а отрицательные значения (уменьшение в процентах) выделены красным цветом. Подробно о том, как настроить такое форматирование, читайте в этой статье.

Считаем проценты в Excel

Пример 2. Расчёт изменения в процентах между строками

В случае, когда Ваши данные расположены в одном столбце, который отражает информацию о продажах за неделю или за месяц, изменение в процентах можно рассчитать по такой формуле:

=(C3-C2)/C2

Здесь C2 это первое значение, а C3 это следующее по порядку значение.

Замечание: Обратите внимание, что, при таком расположении данных в таблице, первую строку с данными необходимо пропустить и записывать формулу со второй строки. В нашем примере это будет ячейка D3.

После того, как Вы запишите формулу и скопируете её во все необходимые строки своей таблицы, у Вас должно получиться что-то похожее на это:

Считаем проценты в Excel

Если Вам нужно рассчитать для каждой ячейки изменение в процентах по сравнению со значением одной конкретной ячейки, используйте абсолютную ссылку на эту ячейку со знаком $, например, так $C$2.

Например, вот так будет выглядеть формула для расчёта процентного изменения для каждого месяца в сравнении с показателем Января (January):

=(C3-$C$2)/$C$2

Когда Вы будете копировать свою формулу из одной ячейки во все остальные, абсолютная ссылка останется неизменной, в то время как относительная ссылка (C3) будет изменяться на C4, C5, C6 и так далее.

Считаем проценты в Excel

Расчёт значения и общей суммы по известному проценту

Как Вы могли убедиться, расчёт процентов в Excel – это просто! Так же просто делается расчёт значения и общей суммы по известному проценту.

Пример 1. Расчёт значения по известному проценту и общей сумме

Предположим, Вы покупаете новый компьютер за $950, но к этой цене нужно прибавить ещё НДС в размере 11%. Вопрос – сколько Вам нужно доплатить? Другими словами, 11% от указанной стоимости – это сколько в валюте?

Нам поможет такая формула:

Total * Percentage = Amount
Общая сумма * Проценты = Значение

Предположим, что Общая сумма (Total) записана в ячейке A2, а Проценты (Percent) – в ячейке B2. В этом случае наша формула будет выглядеть довольно просто =A2*B2 и даст результат $104.50:

Считаем проценты в Excel

Важно запомнить: Когда Вы вручную вводите числовое значение в ячейку таблицы и после него знак %, Excel понимает это как сотые доли от введённого числа. То есть, если с клавиатуры ввести 11%, то фактически в ячейке будет храниться значение 0,11 – именно это значение Excel будет использовать, совершая вычисления.

Другими словами, формула =A2*11% эквивалентна формуле =A2*0,11. Т.е. в формулах Вы можете использовать либо десятичные значения, либо значения со знаком процента – как Вам удобнее.

Пример 2. Расчёт общей суммы по известному проценту и значению

Предположим, Ваш друг предложил купить его старый компьютер за $400 и сказал, что это на 30% дешевле его полной стоимости. Вы хотите узнать, сколько же стоил этот компьютер изначально?

Так как 30% — это уменьшение цены, то первым делом отнимем это значение от 100%, чтобы вычислить какую долю от первоначальной цены Вам нужно заплатить:

100%-30% = 70%

Теперь нам нужна формула, которая вычислит первоначальную цену, то есть найдёт то число, 70% от которого равны $400. Формула будет выглядеть так:

Amount/Percentage = Total
Значение/Процент = Общая сумма

Для решения нашей задачи мы получим следующую форму:

=A2/B2 или =A2/0,7 или =A2/70%

Считаем проценты в Excel

Как увеличить/уменьшить значение на процент

С наступлением курортного сезона Вы замечаете определённые изменения в Ваших привычных еженедельных статьях расходов. Возможно, Вы захотите ввести некоторые дополнительные корректировки к расчёту своих лимитов на расходы.

Чтобы увеличить значение на процент, используйте такую формулу:

=Значение*(1+%)

Например, формула =A1*(1+20%) берёт значение, содержащееся в ячейке A1, и увеличивает его на 20%.

Чтобы уменьшить значение на процент, используйте такую формулу:

=Значение*(1-%)

Например, формула =A1*(1-20%) берёт значение, содержащееся в ячейке A1, и уменьшает его на 20%.

В нашем примере, если A2 это Ваши текущие расходы, а B2 это процент, на который Вы хотите увеличить или уменьшить их значение, то в ячейку C2 нужно записать такую формулу:

Увеличить на процент: =A2*(1+B2)
Уменьшить на процент: =A2*(1-B2)

Считаем проценты в Excel

Как увеличить/уменьшить на процент все значения в столбце

Предположим, что у Вас есть целый столбец, заполненный данными, которые надо увеличить или уменьшить на какой-то процент. При этом Вы не хотите создавать ещё один столбец с формулой и новыми данными, а изменить значения в том же столбце.

Нам потребуется всего 5 шагов для решения этой задачи:

  1. Внесём данные, которые нужно увеличить или уменьшить, в столбец. В нашем примере это столбец B.
  2. В пустой ячейке запишите одну из формул:

    Чтобы увеличить на процент: =1+20%
    Чтобы уменьшить на процент: =1-20%

    Считаем проценты в Excel

В обеих формулах мы взяли 20% для примера, а Вы можете использовать то значение процентов, которое Вам нужно.

  1. Выберите ячейку с формулой (в нашем примере это C2) и скопируйте её, нажав Ctrl+C.
  2. Выделите диапазон ячеек, в котором надо сделать изменение. Щелкните по нему правой кнопкой мыши и в появившемся контекстном меню выберите пункт Paste Special (Специальная вставка).Считаем проценты в Excel
  3. В открывшемся диалоговом окне Paste Special (Специальная вставка) в разделе Paste (Вставить) выберите пункт Values (Значения), а в разделе Operation (Операция) пункт Multiply (Умножить). Затем нажмите ОК.Считаем проценты в Excel

В результате значения в столбце B увеличатся на 20%.

Считаем проценты в Excel

Таким способом можно умножать, делить, складывать или вычитать из целого столбца с данными какой-то процент. Просто введите нужный процент в пустую ячейку и проделайте шаги, описанные выше.

Эти способы помогут Вам в вычислении процентов в Excel. И даже, если проценты никогда не были Вашим любимым разделом математики, владея этими формулами и приёмами, Вы заставите Excel проделать за Вас всю работу.

На сегодня всё, благодарю за внимание!

ОфисГуру
Adblock
detector